arduino-0022

arduino-0022-linux-x64/examples/7.Display/RowColumnScanning/RowColumnScanning.pde

@@ -0,0 +1,114 @@
+/*
+  Row-Column Scanning an 8x8 LED matrix with X-Y input
+ 
+ This example controls an 8x8 LED matrix using two analog inputs
+ 
+ created 27 May 2009
+ modified 4 Sep 2010
+ by Tom Igoe
+ 
+ This example works for the Lumex  LDM-24488NI Matrix. See 
+ http://sigma.octopart.com/140413/datasheet/Lumex-LDM-24488NI.pdf
+ for the pin connections
+ 
+ For other LED cathode column matrixes, you should only need to change 
+ the pin numbers in the row[] and column[] arrays
+ 
+ rows are the anodes
+ cols are the cathodes
+ ---------
+ 
+ Pin numbers:
+ Matrix:
+ * Digital pins 2 through 13,
+ * analog pins 2 through 5 used as digital 16 through 19
+ Potentiometers:
+ * center pins are attached to analog pins 0 and 1, respectively
+ * side pins attached to +5V and ground, respectively.
+ 
+ This example code is in the public domain.
+ 
+ http://www.arduino.cc/en/Tutorial/RowColumnScanning
+ 
+ see also http://www.tigoe.net/pcomp/code/category/arduinowiring/514 for more
+ */
+
+
+// 2-dimensional array of row pin numbers:
+const int row[8] = {
+  2,7,19,5,13,18,12,16 };
+
+// 2-dimensional array of column pin numbers:
+const int col[8] = {
+  6,11,10,3,17,4,8,9  };
+
+// 2-dimensional array of pixels:
+int pixels[8][8];           
+
+// cursor position:
+int x = 5;
+int y = 5;
+
+void setup() {
+  Serial.begin(9600);
+  // initialize the I/O pins as outputs:
+
+  // iterate over the pins:
+  for (int thisPin = 0; thisPin < 8; thisPin++) {
+    // initialize the output pins:
+    pinMode(col[thisPin], OUTPUT); 
+    pinMode(row[thisPin], OUTPUT);  
+    // take the col pins (i.e. the cathodes) high to ensure that
+    // the LEDS are off: 
+    digitalWrite(col[thisPin], HIGH);    
+  }
+
+  // initialize the pixel matrix:
+  for (int x = 0; x < 8; x++) {
+    for (int y = 0; y < 8; y++) {
+      pixels[x][y] = HIGH;
+    }
+  }
+}
+
+void loop() {
+  // read input:
+  readSensors();
+
+  // draw the screen:
+  refreshScreen();
+}
+
+void readSensors() {
+  // turn off the last position:
+  pixels[x][y] = HIGH;
+  // read the sensors for X and Y values:
+  x = 7 - map(analogRead(A0), 0, 1023, 0, 7);
+  y = map(analogRead(A1), 0, 1023, 0, 7);
+  // set the new pixel position low so that the LED will turn on
+  // in the next screen refresh:
+  pixels[x][y] = LOW;
+
+}
+
+void refreshScreen() {
+  // iterate over the rows (anodes):
+  for (int thisRow = 0; thisRow < 8; thisRow++) {
+    // take the row pin (anode) high:
+    digitalWrite(row[thisRow], HIGH);
+    // iterate over the cols (cathodes):
+    for (int thisCol = 0; thisCol < 8; thisCol++) {
+      // get the state of the current pixel;
+      int thisPixel = pixels[thisRow][thisCol];
+      // when the row is HIGH and the col is LOW,
+      // the LED where they meet turns on:
+      digitalWrite(col[thisCol], thisPixel);
+      // turn the pixel off:
+      if (thisPixel == LOW) {
+        digitalWrite(col[thisCol], HIGH);
+      }
+    }
+    // take the row pin low to turn off the whole row:
+    digitalWrite(row[thisRow], LOW);
+  }
+}

arduino-0022-linux-x64/examples/7.Display/barGraph/barGraph.pde

@@ -0,0 +1,60 @@
+/*
+  LED bar graph
+ 
+  Turns on a series of LEDs based on the value of an analog sensor.
+  This is a simple way to make a bar graph display. Though this graph
+  uses 10 LEDs, you can use any number by changing the LED count
+  and the pins in the array.
+  
+  This method can be used to control any series of digital outputs that
+  depends on an analog input.
+ 
+  The circuit:
+   * LEDs from pins 2 through 11 to ground
+ 
+ created 4 Sep 2010
+ by Tom Igoe 
+
+ This example code is in the public domain.
+ 
+ http://www.arduino.cc/en/Tutorial/BarGraph
+ */
+
+
+// these constants won't change:
+const int analogPin = A0;   // the pin that the potentiometer is attached to
+const int ledCount = 10;    // the number of LEDs in the bar graph
+
+int ledPins[] = { 
+  2, 3, 4, 5, 6, 7,8,9,10,11 };   // an array of pin numbers to which LEDs are attached
+
+
+void setup() {
+  // loop over the pin array and set them all to output:
+  for (int thisLed = 0; thisLed < ledCount; thisLed++) {
+    pinMode(ledPins[thisLed], OUTPUT); 
+  }
+}
+
+void loop() {
+  // read the potentiometer:
+  int sensorReading = analogRead(analogPin);
+  // map the result to a range from 0 to the number of LEDs:
+  int ledLevel = map(sensorReading, 0, 1023, 0, ledCount);
+
+  // loop over the LED array:
+  for (int thisLed = 0; thisLed < ledCount; thisLed++) {
+    // if the array element's index is less than ledLevel,
+    // turn the pin for this element on:
+    if (thisLed < ledLevel) {
+      digitalWrite(ledPins[thisLed], HIGH);
+    } 
+    // turn off all pins higher than the ledLevel:
+    else {
+      digitalWrite(ledPins[thisLed], LOW); 
+    }
+  }
+}
+
+
+